# SPDX-FileCopyrightText: 2003-2026 Sébastien Helleu <flashcode@flashtux.org>
#
# SPDX-License-Identifier: GPL-3.0-or-later

set(LIB_GUI_CURSES_SRC
  ../gui-curses.h
  ../gui-curses-bar-window.c ../gui-curses-bar-window.h
  ../gui-curses-chat.c ../gui-curses-chat.h
  ../gui-curses-color.c ../gui-curses-color.h
  ../gui-curses-key.c ../gui-curses-key.h
  ../gui-curses-main.c ../gui-curses-main.h
  ../gui-curses-mouse.c ../gui-curses-mouse.h
  ../gui-curses-term.c
  ../gui-curses-window.c ../gui-curses-window.h
)

find_package(Ncurses)
if(NCURSES_FOUND)
  add_definitions(${NCURSES_CFLAGS})
  # Look for headers only in NCURSES_INCLUDE_PATH: a check with the compiler
  # could find the system headers instead of the ncurses we link with.
  if(EXISTS "${NCURSES_INCLUDE_PATH}/ncurses.h")
    add_definitions(-DHAVE_NCURSES_H)
  elseif(EXISTS "${NCURSES_INCLUDE_PATH}/ncursesw/ncurses.h")
    add_definitions(-DHAVE_NCURSESW_CURSES_H)
  endif()
else()
  message(SEND_ERROR "Ncurses not found")
endif()

include_directories(.. ../../core ../../plugins ${NCURSES_INCLUDE_PATH})

add_library(weechat_gui_curses_normal STATIC ${LIB_GUI_CURSES_SRC})

set(EXECUTABLE weechat)

add_executable(${EXECUTABLE} main.c)

target_link_libraries(${EXECUTABLE}
  weechat_core
  weechat_plugins
  weechat_gui_common
  weechat_gui_curses_normal
  ${EXTRA_LIBS}
  ${NCURSES_LIBRARY}
  coverage_config
)

# Create a symbolic link weechat-curses -> weechat
# This link is created for compatibility with old versions on /upgrade.
# It may be removed in future.
add_custom_command(
  TARGET ${EXECUTABLE}
  POST_BUILD
  COMMAND ${CMAKE_COMMAND} -E remove -f "weechat-curses${CMAKE_EXECUTABLE_SUFFIX}"
  COMMAND ${CMAKE_COMMAND} -E create_symlink "weechat${CMAKE_EXECUTABLE_SUFFIX}" "weechat-curses${CMAKE_EXECUTABLE_SUFFIX}"
  WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
  COMMENT "Creating symbolic link ${EXECUTABLE}-curses${CMAKE_EXECUTABLE_SUFFIX}"
)
list(APPEND CMAKE_INSTALL_MANIFEST_FILES "${CMAKE_INSTALL_PREFIX}/bin/weechat-curses${CMAKE_EXECUTABLE_SUFFIX}")

# Install executable and symbolic link.
install(TARGETS ${EXECUTABLE} RUNTIME DESTINATION bin)
install(FILES "${CMAKE_CURRENT_BINARY_DIR}/${EXECUTABLE}-curses${CMAKE_EXECUTABLE_SUFFIX}" DESTINATION bin)
